Vlookup 函数最经典的 10 种用法

原文标题：《Vlookup 函数最经典的 10 种用法，用过的人都说香，错过后悔一个亿！》

对于得了函数恐惧症的 Excel 小白来讲，最最最最最痛苦的事情是什么？

不知道用哪个函数？

是我明明知道这个函数的名字，却不知道怎么写公式！

就比如在 Excel 界「称霸一方」的查找函数 Vlookup，悬浮窗早已给出了答案，但在小白眼里就是一堆神秘字符

所以今天，我准备了 10 个常见常用的 Vlookup 经典用法，助力大家更快掌握这个函数。

单条件查找

根据条件「葡萄」，查找「数量」。

公式：

=VLOOKUP(E2,B2:C21,2,FALSE)

Vlookup 基本语法见下图：

隐藏乱码

公式：

=IFERROR(VLOOKUP(E2,B2:C21,2,FALSE),)

公式说明："" 的含义是，如果前面的 VLOOKUP 函数中存在错误的参数，那么在显示结果的单元格中显示为空。

多条件查找

根据两个条件「姓名」和「科目」，查找「成绩」。

公式：

=VLOOKUP(F3&G3,A:D,4,FALSE)

公式说明：添加辅助列，将两个条件用 & 符号组合在一起，变成一个条件，再用 Vlookup 函数的基础语法进行查找。

模糊查找

根据「课程简称」，查找「课程全称」。

公式：

=VLOOKUP("*"&C2&"*",$A$1:$A$8,1,FALSE)

公式说明：将要查找的简称前后都用 & 连接符加上一个「*」，就可以来替代包含该简称的数据了。

分段统计

根据「金额」，查看所在「区间」。

公式：

=VLOOKUP(C2,$F$2:$G$9,2,TRUE)

公式说明：

❶ 使用了 Vlookup 近似匹配的特殊用法，第四参数，需用 True，或者 1；

❷ 区间起点必须是第 2 参数区域的首列；

❸ 第 2 参数区域需用 $ 锁定，确保不偏移。

一对多查找

根据「姓名」，查找一月、二月、三月的「销售额」。

公式：

=VLOOKUP($A15,$A$2:$D$12,COLUMN(B1),0)

公式说明：

Column (B1) 的结果是 2，当公式向右复制时可以生成 3，4，5，……

逆向查找

根据 B 列的「水果」，查找 A 列对应的「编号」。

公式：

=VLOOKUP(E2,IF({1,0},B2:B21,A2:A21),2,FALSE)

公式说明：利用 IF 函数构造数组，将 B 列和 A 列位置互换，再用 Vlookup 函数正常查找。

跨表查找

根据「水果」，在多个表格查找「数量」。

公式：

=VLOOKUP(A2,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT({"水果 1";"水果 2";"水果 3"}&"!A:A"),A2),{"水果 1";"水果 2";"水果 3"})&"!A:B"),2,0)

▲ 左右滑动查看

公式说明：

A2：Vlookup 的查找值；

{...} 数组里的内容：多个工作表名称，用分号分隔；

A:A：查找值在各个表中的哪一列，需要确定各个表的该列是否存在这个查找值；

A:B：vlookup 的查找区域；

2：返回值的列数，姓名是在 A:B 区域中的第 2 列。

交叉查询

根据「列号」和「行号」，查找「姓名」。

公式：

=VLOOKUP(I2,A2:F11,MATCH(I1,A1:F1,0))

公式说明：

用 MATCH 得出的结果即为 VLOOKUP 函数第 3 参数，返回被查找区域的第几列。

查找最后一个值

查询「水果」的「最后一次销量」。

公式：

=VLOOKUP(COUNTIF($C$2:$C$11,F2)&F2,$B$1:$D$11,3,FALSE)

公式说明：关于用 Countif 函数做辅助列查找最后一个出现的值相关的做法，之前有一篇文章讲过：不管查找第几次出现的数据，用 Vlookup 函数这样做，超简单！

Vlookup 的作用非常之强大，祝愿大家早日掌握！

本文来自微信公众号：秋叶 Excel （ID：excel100），作者：竺兰，编辑：竺兰

广告声明：文内含有的对外跳转链接（包括不限于超链接、二维码、口令等形式），用于传递更多信息，节省甄选时间，结果仅供参考，IT之家所有文章均包含本声明。